asp下制做行背景颜色交替变换的表格

<%
Const adInteger = 3
Const adVarChar = 200 
'' 声明变量
Dim myRecordset 
Dim iLetter     
Dim Field       
Dim strAltColor 
Dim bColor      
bColor = False

'' 此例利用内存中的recordset,你需要做的只是修改你的数据显示的部分就可以了。
Set myRecordset = Server.CreateObject("ADODB.Recordset")
myRecordset.Fields.Append "ID", adInteger
myRecordset.Fields.Append "Title", adVarChar, 25
myRecordset.Fields.Append "Description", adVarChar, 255

myRecordset.Open

'' Fill RS with sample data:
For iLetter = Asc("A") To Asc("M")
 myRecordset.AddNew
 myRecordset.Fields("ID").Value          = iLetter - 64
 myRecordset.Fields("Title").Value       = "字母：" & Chr(iLetter)
 myRecordset.Fields("Description").Value = "这里测试字母：" & Chr(iLetter) & "."
 myRecordset.Update
Next ''iLetter

''移动到头部开始位置，以便下面的循环开始.
myRecordset.MoveFirst


'' 在表格中显示数据

Response.Write "<table border=""0"" cellspacing=""0"" cellpadding=""3"">" & vbCrLf

''表头
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
 Response.Write vbTab & vbTab & "<td bgcolor=""#CCCCCC""><strong>"
 Response.Write Field.Name
 Response.Write "</strong></td>" & vbCrLf
Next ''Field
Response.Write vbTab & "</tr>" & vbCrLf

Do While Not myRecordset.EOF
 '' 循环改变单元格的背景颜色
 bColor = Not bColor
 If bColor Then
  strAltColor = "#FFFFFF"
 Else
  strAltColor = "#FF8040"
 End If

 ''循环改变单元格的背景颜色
 Response.Write vbTab & "<tr>" & vbCrLf
 For Each Field in myRecordset.Fields
  Response.Write vbTab & vbTab & "<td bgcolor="""
  Response.Write strAltColor
  Response.Write """>" & Field.Value & "</td>" & vbCrLf
 Next ''Field
 Response.Write vbTab & "</tr>" & vbCrLf

 myRecordset.MoveNext
Loop

'' End the table
Response.Write "</table>" & vbCrLf

'' 关闭对象、释放资源
myRecordset.Close
Set myRecordset = Nothing
%>